第27章 Earプラグイン

To use the Ear plugin, include the following in your build script:

Earプラグインを使うには、ビルドスクリプトに以下を含めてください:

apply plugin: 'ear'

The Ear plugin adds the following tasks to the project.

Earプラグインはプロジェクトに以下のタスクを追加します。

The Ear plugin adds the following dependencies to tasks added by the base plugin.

Earプラグインはベースプラグインが追加したタスクに以下の依存関係を追加します。

The Ear plugin adds two dependency configurations: deploy and earlib. All dependencies in the deploy configuration are placed in the root of the EAR archive, and are not transitive. All dependencies in the earlib configuration are placed in the 'lib' directory in the EAR archive and are transitive.

Earプラグインは2つの依存関係コンフィグレーションを追加します: deployおよびearlib deployコンフィグレーションにおけるすべての依存関係はEARアーカイブのルートに配置され、それらは推移的ではありません。 earlibコンフィグレーションにおけるすべての依存関係はEARアーカイブの'lib'ディレクトリに配置され、推移的です。

These properties are provided by a EarPluginConvention convention object.

これらのプロパティは規約オブジェクトEarPluginConventionが提供します。

The default behavior of the Ear task is to copy the content of src/main/application to the root of the archive. If your application directory doesn't contain a META-INF/application.xml deployment descriptor then one will be generated for you.

Earタスクのデフォルトのふるまいは、src/main/applicationの内容をアーカイブのルートにコピーすることです。 applicationディレクトリがデプロイメントディスクリプタMETA-INF/application.xmlを含まない場合は、生成してくれます。

The Ear class in the API documentation has additional useful information.

Earも参照してみてください。

Here is an example with the most important customization options:

最も重要なカスタマイズオプションを使う例はこちらです:

apply plugin: 'ear'
apply plugin: 'java'

repositories { mavenCentral() }

dependencies {
    // The following dependencies will be the ear modules and
    // will be placed in the ear root
    deploy project(':war')

    // The following dependencies will become ear libs and will
    // be placed in a dir configured via the libDirName property
    earlib group: 'log4j', name: 'log4j', version: '1.2.15', ext: 'jar'
}

ear {
    appDirName 'src/main/app'  // use application metadata found in this folder
    // put dependent libraries into APP-INF/lib inside the generated EAR
    libDirName 'APP-INF/lib'
    deploymentDescriptor {  // custom entries for application.xml:
//      fileName = "application.xml"  // same as the default value
//      version = "6"  // same as the default value
        applicationName = "customear"
        initializeInOrder = true
        displayName = "Custom Ear"  // defaults to project.name
        // defaults to project.description if not set
        description = "My customized EAR for the Gradle documentation"
//      libraryDirectory = "APP-INF/lib"  // not needed, above libDirName setting does this
//      module("my.jar", "java")  // won't deploy as my.jar isn't deploy dependency
//      webModule("my.war", "/")  // won't deploy as my.war isn't deploy dependency
        securityRole "admin"
        securityRole "superadmin"
        withXml { provider -> // add a custom node to the XML
            provider.asNode().appendNode("data-source", "my/data/source")
        }
    }
}

You can also use customization options that the Ear task provides, such as from and metaInf.

fromやmetaInfといった、Earタスクが提供するカスタマイズオプションも利用できます。

You may already have appropriate settings in a application.xml file and want to use that instead of configuring the ear.deploymentDescriptor section of the build script. To accommodate that goal, place the META-INF/application.xml in the right place inside your source folders (see the appDirName property). The file contents will be used and the explicit configuration in the ear.deploymentDescriptor will be ignored.

ear.deploymentDescriptorセクションで設定するかわりに、既にapplication.xmlがあって、それを使いたいとしましょう。 そのためにはMETA-INF/application.xmlをソースフォルダ内の適切な場所に配置します(appDirNameプロパティを参照)。 既存のファイルの内容が利用され、ear.deploymentDescriptorの設定内容は無視されます。