第53章 Mavenプラグイン

With Gradle you can deploy to remote Maven repositories or install to your local Maven repository. This includes all Maven metadata manipulation and works also for Maven snapshots. In fact, Gradle's deployment is 100 percent Maven compatible as we use the native Maven Ant tasks under the hood.

Gradleでは、リモートMavenリポジトリにデプロイすることも、ローカルMavenリポジトリにインストールすることもできます。 これにはすべてのMavenメタデータの操作が含まれ、Mavenスナップショットに対しても適用できます。 実際、Gradleのデプロイは、ネィティブのMaven Antタスクを内部で利用するのと同じく、100%Maven互換です。

Deploying to a Maven repository is only half the fun if you don't have a POM. Fortunately Gradle can generate this POM for you using the dependency information it has.

もしPOMがないとしたら、Mavenリポジトリへのデプロイは楽しさ半減です。 幸運なことに、GradleはPOM自身の持つ依存関係の情報を用いて、このPOMを生成してくれます

Let's assume your project produces just the default jar file. Now you want to deploy this jar file to a remote Maven repository.

プロジェクトが単にデフォルトのJARファイルを生成するだけだとしましょう。 このJARファイルをリモートMavenリポジトリにデプロイしたいとします。

apply plugin: 'maven'

uploadArchives {
    repositories {
        mavenDeployer {
            repository(url: "file://localhost/tmp/myRepo/")
        }
    }
}

That is all. Calling the uploadArchives task will generate the POM and deploys the artifact and the POM to the specified repository.

これが全てです。 uploadArchivesタスクを呼び出すことでPOMが生成され、 アーティファクトとPOMが指定されたリポジトリにデプロイされます。

There is more work to do if you need support for other protocols other than file. In this case the native Maven code we delegate to needs additional libraries. Which libraries are needed depends on what protocol you plan to use. The available protocols and the corresponding libraries are listed in 表53.3「Mavenデプロイに対するプロトコルJARProtocol jars for Maven deployment」 (those libraries have transitive dependencies which have transitive dependencies). ^[28] For example, to use the ssh protocol you can do:

file以外のプロトコルをサポートする必要があるなら、他にも少しやるべきことがあります。 この場合、処理を委譲するネィティブMavenコードが追加のライブラリを必要とします。 どのライブラリが必要になるかは、必要なプロトコルによります。 利用可能なプロトコルと対応するライブラリは表53.3「Mavenデプロイに対するプロトコルJARProtocol jars for Maven deployment」にリストアップされています (推移的な依存関係を持つこれらのライブラリは、さらに推移的な依存関係を持ちます)。 ^[29] 例えば、SSHプロトコルを使うには次のようにできます:

configurations {
    deployerJars
}

repositories {
    mavenCentral()
}

dependencies {
    deployerJars "org.apache.maven.wagon:wagon-ssh:2.2"
}

uploadArchives {
    repositories.mavenDeployer {
        configuration = configurations.deployerJars
        repository(url: "scp://repos.mycompany.com/releases") {
            authentication(userName: "me", password: "myPassword")
        }
    }
}

There are many configuration options for the Maven deployer. The configuration is done via a Groovy builder. All the elements of this tree are Java beans. To configure the simple attributes you pass a map to the bean elements. To add bean elements to its parent, you use a closure. In the example above repository and authentication are such bean elements. 表53.4「MavenDeployerのコンフィグレーション要素Configuration elements of the MavenDeployer」 lists the available bean elements and a link to the Javadoc of the corresponding class. In the Javadoc you can see the possible attributes you can set for a particular element.

Mavenデプロイヤーには多くのコンフィグレーションオプションがあります。 コンフィグレーションはGroovyビルダーで行うことができます。 このツリーのすべての要素はJava beansです。 単純な属性を設定するためには、beanの要素にmapを渡してやります。 親要素に別のbean要素を追加するには、クロージャを使います。 上記の例では、repositoryとauthenticationがbean要素です。 利用可能なbean要素と対応するクラスのJavaDocへのリンクは、表53.4「MavenDeployerのコンフィグレーション要素Configuration elements of the MavenDeployer」にリストアップされています。 JavaDocでは特定の要素にセットできる属性を確認できます。

In Maven you can define repositories and optionally snapshot repositories. If no snapshot repository is defined, releases and snapshots are both deployed to the repository element. Otherwise snapshots are deployed to the snapshotRepository element.

Mavenではリポジトリに加えて、オプションでスナップショットリポジトリを定義できます。 スナップショットリポジトリが定義されていない場合、 リリースとスナップショットの両方がrepository要素で指定された先にデプロイされます。 そうでない場合は、スナップショットはsnapshotRepository要素で指定された先にデプロイされます。

The Maven plugin adds an install task to your project. This task depends on all the archives task of the archives configuration. It installs those archives to your local Maven repository. If the default location for the local repository is redefined in a Maven settings.xml, this is considered by this task.

Mavenプラグインはプロジェクトにinstallタスクを追加します。 このタスクはarchivesコンフィグレーションのすべてのarchivesタスクに依存します。 これらのアーカイブはローカルMavenリポジトリにインストールされます。 もし、ローカルリポジトリの場所がMavenのsettings.xmlで再定義されていたら、このタスクはそれを反映します。

When deploying an artifact to a Maven repository, Gradle automatically generates a POM for it. The groupId, artifactId, version and packaging elements used for the POM default to the values shown in the table below. The dependency elements are created from the project's dependency declarations.

Mavenリポジトリにアーティファクトをデプロイする際、Gradleは自動的にデプロイ用のPOMを生成します。 POMにデフォルトで設定されるgroupId、artifactId、version、packaging要素の値は以下の表を参照してください。 dependency要素は、プロジェクトで宣言されている依存関係設定から作成されます。

Here, uploadTask and archiveTask refer to the tasks used for uploading and generating the archive, respectively (for example uploadArchives and jar). archiveTask.baseName defaults to project.archivesBaseName which in turn defaults to project.name.

ここで、uploadTaskとarchiveTaskは、それぞれ、実際にアーカイブをアップロードするタスクと生成するタスクのことを指しています(例えば、uploadArchivesとjar)。 archiveTask.baseNameのデフォルト値はproject.archivesBaseNameで、そのデフォルト値はproject.nameです。

Generated POMs can be found in <buildDir>/poms. They can be further customized via the MavenPom API. For example, you might want the artifact deployed to the Maven repository to have a different version or name than the artifact generated by Gradle. To customize these you can do:

生成されたPOMは、<buildDir>/pomsに出力されます。そのPOMは、さらにMavenPom APIでカスタマイズすることができます。 例えば、Mavenにデプロイするアーティファクトには、Gradleで生成するアーティファクトとは別のバージョンと名前を持たせたくなるかもしれません。このようなカスタマイズを行うには、以下のようにします。

uploadArchives {
    repositories {
        mavenDeployer {
            repository(url: "file://localhost/tmp/myRepo/")
            pom.version = '1.0Maven'
            pom.artifactId = 'myMavenName'
        }
    }
}

To add additional content to the POM, the pom.project builder can be used. With this builder, any element listed in the Maven POM reference can be added.

POMに追加的な内容を加えるには、pom.projectビルダーを使います。 このビルダーを使えば、Maven POMリファレンスに載っている全ての要素を追加することができます。

uploadArchives {
    repositories {
        mavenDeployer {
            repository(url: "file://localhost/tmp/myRepo/")
            pom.project {
                licenses {
                    license {
                        name 'The Apache Software License, Version 2.0'
                        url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                        distribution 'repo'
                    }
                }
            }
        }
    }
}

Note: groupId, artifactId, version, and packaging should always be set directly on the pom object.

注意: groupId、artifactId、versionおよびpackagingは、常にpomオブジェクトに直接設定するべきです。

def installer = install.repositories.mavenInstaller
def deployer = uploadArchives.repositories.mavenDeployer

[installer, deployer]*.pom*.whenConfigured {pom ->
    pom.dependencies.find {dep -> dep.groupId == 'group3' && dep.artifactId == 'runtime' }.optional = true
}

If you have more than one artifact to publish, things work a little bit differently. See 「複数アーティファクトを含むプロジェクトMultiple artifacts per project」.

2つ以上のアーティファクトを公開したい場合は、すこし難しくなります。「複数アーティファクトを含むプロジェクトMultiple artifacts per project」を参照してください。

To customize the settings for the Maven installer (see「ローカルリポジトリへのインストールInstalling to the local repository」), you can do:

Mavenインストーラー(「ローカルリポジトリへのインストールInstalling to the local repository」参照)の設定をカスタマイズするには、次のようにします。

install {
    repositories.mavenInstaller {
        pom.version = '1.0Maven'
        pom.artifactId = 'myName'
    }
}

uploadArchives {
    repositories {
        mavenDeployer {
            repository(url: "file://localhost/tmp/myRepo/")
            addFilter('api') {artifact, file ->
                artifact.name == 'api'
            }
            addFilter('service') {artifact, file ->
                artifact.name == 'service'
            }
            pom('api').version = 'mySpecialMavenVersion'
        }
    }
}

task mappings << {
    println conf2ScopeMappings.mappings
}